mirror of
https://github.com/microsoft/vscode.git
synced 2025-12-25 12:47:14 +00:00
b5a6aa14a8
* feat: move from yarn to npm * chore: skip yarn.lock files * fix: playwright download * chore: fix compile and hygiene * chore: bump vsce@2.17.0 Refs8b49e9dfdf* test: update results for bat and sh colorizer tests * fix: add missing lock files for windows * fix: switch to legacy-peer-deps * chore: update markdown-it@14.1.0 Refs737c95a129esbuild step in extensions-ci-pr was previously using markdown-it from root which had userland punycode and was able to compile successfully. * ci: increase pr timeout for windows integration tests * chore: fix product build * build: ignore extension dev dependency for rcedit * build: fix working directory inside container * build: fix dependency generation * npm: update dependencies * ci: use global npmrc * ci: update cache * ci: setup global npmrc for private npm auth * build: fix extension bundling * chore: sync npm dependencies * ci: debug env variables for container * ci: fix win32 cli pipeline * build: fix npmrc config usage for build/ and remote/ dirs * fix: windows build * fix: container builds * fix: markdown-language-features tests and bundling ``` [03:58:22] Error: Command failed: /Users/demohan/.nvm/versions/node/v20.15.1/bin/node /Users/demohan/github/vscode/extensions/markdown-language-features/esbuild-notebook.js --outputRoot /Users/demohan/github/vscode/.build/extensions/markdown-language-features ✘ [ERROR] Could not resolve "punycode" extensions/markdown-language-features/node_modules/markdown-it/lib/index.js:14:27: 14 │ var punycode = require('punycode'); ╵ ~~~~~~~~~~ The package "punycode" wasn't found on the file system but is built into node. Are you trying to bundle for node? You can use "platform: 'node'" to do that, which will remove this error. ``` Adds userland package based onbeed9aee2c* fix: container builds for distro * chore: update yarn occurrences * fixup! chore: bump vsce@2.17.0 Uses the closest version to `main` branch that does not included3cc84cdecwhile still having the fix8b49e9dfdf* chore: sync npm dependencies * chore: sync npm dependencies * chore: sync npm dependencies * chore: throw error when yarn is used for installation * chore: add review feedback * chore: switch exec => run where needed * chore: npm sync dependencies * fix: markdown-language-features bundling ``` ✘ [ERROR] Could not resolve "punycode" extensions/markdown-language-features/node_modules/markdown-it/lib/index.js:14:27: 14 │ var punycode = require('punycode'); ╵ ~~~~~~~~~~ The package "punycode" wasn't found on the file system but is built into node. Are you trying to bundle for node? You can use "platform: 'node'" to do that, which will remove this error. ``` Adds missing userland package based on markdown-it/markdown-it@beed9ae, can be removed once we update markdown-it >= 14.1.0 * ci: rename no-yarn-lock-changes.yml * chore: sync npm dependencies * ci: restore no-yarn-lock-changes.yml We can disable it in a separate PR to keep the required checks happy and also need workflow edit perms. * chore: sync npm dependencies * ci: rebuild cache * ci: fix no-package-lock-changes.yml * chore: bump distro * chore: rm yarn.lock files * chore: rm yarn.lock files without dependencies * chore: add vscode-selfhost-import-aid to postinstall dirs * chore: bump distro
120 lines
4.2 KiB
Batchfile
120 lines
4.2 KiB
Batchfile
@echo off
|
|
setlocal
|
|
|
|
pushd %~dp0\..
|
|
|
|
set VSCODEUSERDATADIR=%TEMP%\vscodeuserfolder-%RANDOM%-%TIME:~6,2%
|
|
set VSCODECRASHDIR=%~dp0\..\.build\crashes
|
|
set VSCODELOGSDIR=%~dp0\..\.build\logs\integration-tests
|
|
|
|
:: Figure out which Electron to use for running tests
|
|
if "%INTEGRATION_TEST_ELECTRON_PATH%"=="" (
|
|
chcp 65001
|
|
set INTEGRATION_TEST_ELECTRON_PATH=.\scripts\code.bat
|
|
set VSCODE_BUILD_BUILTIN_EXTENSIONS_SILENCE_PLEASE=1
|
|
|
|
echo Running integration tests out of sources.
|
|
) else (
|
|
set VSCODE_CLI=1
|
|
set ELECTRON_ENABLE_LOGGING=1
|
|
|
|
echo Running integration tests with '%INTEGRATION_TEST_ELECTRON_PATH%' as build.
|
|
)
|
|
|
|
echo Storing crash reports into '%VSCODECRASHDIR%'.
|
|
echo Storing log files into '%VSCODELOGSDIR%'.
|
|
|
|
|
|
:: Tests standalone (AMD)
|
|
|
|
echo.
|
|
echo ### node.js integration tests
|
|
call .\scripts\test.bat --runGlob **\*.integrationTest.js %*
|
|
if %errorlevel% neq 0 exit /b %errorlevel%
|
|
|
|
|
|
:: Tests in the extension host
|
|
|
|
set API_TESTS_EXTRA_ARGS=--disable-telemetry --skip-welcome --skip-release-notes --crash-reporter-directory=%VSCODECRASHDIR% --logsPath=%VSCODELOGSDIR% --no-cached-data --disable-updates --use-inmemory-secretstorage --disable-extensions --disable-workspace-trust --user-data-dir=%VSCODEUSERDATADIR%
|
|
|
|
echo.
|
|
echo ### API tests (folder)
|
|
call "%INTEGRATION_TEST_ELECTRON_PATH%" %~dp0\..\extensions\vscode-api-tests\testWorkspace --enable-proposed-api=vscode.vscode-api-tests --extensionDevelopmentPath=%~dp0\..\extensions\vscode-api-tests --extensionTestsPath=%~dp0\..\extensions\vscode-api-tests\out\singlefolder-tests %API_TESTS_EXTRA_ARGS%
|
|
if %errorlevel% neq 0 exit /b %errorlevel%
|
|
|
|
echo.
|
|
echo ### API tests (workspace)
|
|
call "%INTEGRATION_TEST_ELECTRON_PATH%" %~dp0\..\extensions\vscode-api-tests\testworkspace.code-workspace --enable-proposed-api=vscode.vscode-api-tests --extensionDevelopmentPath=%~dp0\..\extensions\vscode-api-tests --extensionTestsPath=%~dp0\..\extensions\vscode-api-tests\out\workspace-tests %API_TESTS_EXTRA_ARGS%
|
|
if %errorlevel% neq 0 exit /b %errorlevel%
|
|
|
|
echo.
|
|
echo ### Colorize tests
|
|
call npm run test-extension -l vscode-colorize-tests
|
|
if %errorlevel% neq 0 exit /b %errorlevel%
|
|
|
|
echo.
|
|
echo ### TypeScript tests
|
|
call "%INTEGRATION_TEST_ELECTRON_PATH%" %~dp0\..\extensions\typescript-language-features\test-workspace --extensionDevelopmentPath=%~dp0\..\extensions\typescript-language-features --extensionTestsPath=%~dp0\..\extensions\typescript-language-features\out\test\unit %API_TESTS_EXTRA_ARGS%
|
|
if %errorlevel% neq 0 exit /b %errorlevel%
|
|
|
|
echo.
|
|
echo ### Markdown tests
|
|
call npm run test-extension -l markdown-language-features
|
|
if %errorlevel% neq 0 exit /b %errorlevel%
|
|
|
|
echo.
|
|
echo ### Emmet tests
|
|
call "%INTEGRATION_TEST_ELECTRON_PATH%" %~dp0\..\extensions\emmet\test-workspace --extensionDevelopmentPath=%~dp0\..\extensions\emmet --extensionTestsPath=%~dp0\..\extensions\emmet\out\test %API_TESTS_EXTRA_ARGS%
|
|
if %errorlevel% neq 0 exit /b %errorlevel%
|
|
|
|
echo.
|
|
echo ### Git tests
|
|
for /f "delims=" %%i in ('node -p "require('fs').realpathSync.native(require('os').tmpdir())"') do set TEMPDIR=%%i
|
|
set GITWORKSPACE=%TEMPDIR%\git-%RANDOM%
|
|
mkdir %GITWORKSPACE%
|
|
call "%INTEGRATION_TEST_ELECTRON_PATH%" %GITWORKSPACE% --extensionDevelopmentPath=%~dp0\..\extensions\git --extensionTestsPath=%~dp0\..\extensions\git\out\test %API_TESTS_EXTRA_ARGS%
|
|
if %errorlevel% neq 0 exit /b %errorlevel%
|
|
|
|
echo.
|
|
echo ### Ipynb tests
|
|
call npm run test-extension -l ipynb
|
|
if %errorlevel% neq 0 exit /b %errorlevel%
|
|
|
|
echo.
|
|
echo ### Notebook Output tests
|
|
call npm run test-extension -l notebook-renderers
|
|
if %errorlevel% neq 0 exit /b %errorlevel%
|
|
|
|
echo.
|
|
echo ### Configuration editing tests
|
|
set CFWORKSPACE=%TEMPDIR%\cf-%RANDOM%
|
|
mkdir %CFWORKSPACE%
|
|
call npm run test-extension -l configuration-editing
|
|
if %errorlevel% neq 0 exit /b %errorlevel%
|
|
|
|
echo.
|
|
echo ### GitHub Authentication tests
|
|
call npm run test-extension -l github-authentication
|
|
if %errorlevel% neq 0 exit /b %errorlevel%
|
|
|
|
:: Tests standalone (CommonJS)
|
|
|
|
echo.
|
|
echo ### CSS tests
|
|
call %~dp0\node-electron.bat %~dp0\..\extensions\css-language-features/server/test/index.js
|
|
if %errorlevel% neq 0 exit /b %errorlevel%
|
|
|
|
echo.
|
|
echo ### HTML tests
|
|
call %~dp0\node-electron.bat %~dp0\..\extensions\html-language-features/server/test/index.js
|
|
if %errorlevel% neq 0 exit /b %errorlevel%
|
|
|
|
|
|
:: Cleanup
|
|
|
|
rmdir /s /q %VSCODEUSERDATADIR%
|
|
|
|
popd
|
|
|
|
endlocal
|