mirror of
https://github.com/transmission/transmission.git
synced 2026-02-15 07:26:49 +00:00
8dea0e863f
* Revert "build(cmake): support building with (almost) all system 3rd-party libraries (#7554)"
This reverts commit a89ca4f2c9.
* fixup! refactor: use a map of getters, setters for `session_get` and `session_set` properties (#8024)
fix: capture-by-reference error in session_accessors()
* fix: 'Qt depends on a UTF-8 locale' CI warning
* fix: 'qt.qpa.xcb: could not connect to display' CI error
62 lines
1.4 KiB
CMake
62 lines
1.4 KiB
CMake
add_executable(${TR_NAME}-daemon)
|
|
|
|
target_sources(${TR_NAME}-daemon
|
|
PRIVATE
|
|
daemon.cc
|
|
daemon.h
|
|
daemon-posix.cc
|
|
daemon-win32.cc)
|
|
|
|
tr_allow_compile_if(
|
|
[=[[WIN32]]=]
|
|
daemon-win32.cc
|
|
[=[[NOT WIN32]]=]
|
|
daemon-posix.cc)
|
|
|
|
target_compile_definitions(${TR_NAME}-daemon
|
|
PRIVATE
|
|
$<$<BOOL:${WITH_SYSTEMD}>:WITH_SYSTEMD>)
|
|
|
|
tr_target_compile_definitions_for_headers(${TR_NAME}-daemon
|
|
PRIVATE
|
|
sys/signalfd.h)
|
|
|
|
tr_target_compile_definitions_for_functions(${TR_NAME}-daemon
|
|
PRIVATE
|
|
daemon
|
|
syslog)
|
|
|
|
target_include_directories(${TR_NAME}-daemon SYSTEM
|
|
PRIVATE
|
|
$<$<BOOL:${WITH_SYSTEMD}>:${SYSTEMD_INCLUDE_DIRS}>)
|
|
|
|
target_link_libraries(${TR_NAME}-daemon
|
|
PRIVATE
|
|
${TR_NAME}
|
|
libevent::event
|
|
fmt::fmt-header-only
|
|
$<$<BOOL:${WITH_SYSTEMD}>:${SYSTEMD_LIBRARIES}>)
|
|
|
|
tr_win32_app_info(${TR_NAME}-daemon
|
|
"Transmission Daemon"
|
|
"${TR_NAME}-daemon"
|
|
"${TR_NAME}-daemon.exe")
|
|
|
|
install(
|
|
TARGETS ${TR_NAME}-daemon
|
|
DESTINATION ${CMAKE_INSTALL_BINDIR})
|
|
|
|
if(INSTALL_DOC)
|
|
install(
|
|
FILES ${TR_NAME}-daemon.1
|
|
DESTINATION ${CMAKE_INSTALL_MANDIR}/man1)
|
|
endif()
|
|
|
|
if (WITH_SYSTEMD)
|
|
configure_file("${TR_NAME}-daemon.service.in" "${TR_NAME}-daemon.service" @ONLY)
|
|
|
|
install(
|
|
FILES "${CMAKE_CURRENT_BINARY_DIR}/${TR_NAME}-daemon.service"
|
|
DESTINATION lib/systemd/system)
|
|
endif()
|