mirror of
https://github.com/microsoft/vscode.git
synced 2026-08-22 04:02:15 +01:00
9187366d2e
* test: probe Windows batch exit propagation (Written by Copilot) Co-authored-by: Copilot <223556219+Copilot@users.noreply.github.com> * fix: preserve Windows batch failure exit codes Move failure exits outside parenthesized command blocks, where cmd.exe otherwise returns zero to the caller. (Written by Copilot) Co-authored-by: Copilot <223556219+Copilot@users.noreply.github.com> * test: remove Windows exit probe The controlled CI runs captured the failure and validated the top-level failure labels, so remove the temporary diagnostics. (Written by Copilot) Co-authored-by: Copilot <223556219+Copilot@users.noreply.github.com> * test: stabilize Agent Host E2E on Windows Keep portable shell and plugin scenarios enabled while gating three documented Windows persistence and changeset gaps. (Written by Copilot) Co-authored-by: Copilot <223556219+Copilot@users.noreply.github.com> * test: gate unsupported Windows Agent Host E2E Document and skip Windows-only scratch cleanup, custom terminal metadata, and client-plugin hook gaps. (Written by Copilot) Co-authored-by: Copilot <223556219+Copilot@users.noreply.github.com> * test: gate stale Windows discard summaries Document and skip the final tracked-change discard variant whose Windows changeset summaries do not refresh. (Written by Copilot) Co-authored-by: Copilot <223556219+Copilot@users.noreply.github.com> --------- Co-authored-by: Copilot <223556219+Copilot@users.noreply.github.com>
59 lines
1.1 KiB
Batchfile
59 lines
1.1 KiB
Batchfile
@echo off
|
|
setlocal enabledelayedexpansion
|
|
|
|
set ROOT=%~dp0..
|
|
set CONTAINER=
|
|
set ARCH=amd64
|
|
set REGISTRY=vscodehub.azurecr.io/vscode-linux-build-agent/sanity-tests
|
|
set ARGS=
|
|
|
|
:parse_args
|
|
if "%~1"=="" goto :done_parsing
|
|
if "%~1"=="--container" (
|
|
set CONTAINER=%~2
|
|
shift & shift
|
|
goto :parse_args
|
|
)
|
|
if "%~1"=="--arch" (
|
|
set ARCH=%~2
|
|
shift & shift
|
|
goto :parse_args
|
|
)
|
|
set "ARGS=!ARGS! %~1"
|
|
shift
|
|
goto :parse_args
|
|
|
|
:done_parsing
|
|
if "%CONTAINER%"=="" (
|
|
echo Error: --container is required
|
|
goto :failed
|
|
)
|
|
goto :run
|
|
|
|
:failed
|
|
endlocal
|
|
exit /b 1
|
|
|
|
:run
|
|
|
|
set HOST_ARCH=amd64
|
|
if "%PROCESSOR_ARCHITECTURE%"=="ARM64" set HOST_ARCH=arm64
|
|
if not "%ARCH%"=="%HOST_ARCH%" (
|
|
echo Setting up QEMU emulation for %ARCH% on %HOST_ARCH% host
|
|
docker run --privileged --rm tonistiigi/binfmt --install all >nul 2>&1
|
|
)
|
|
|
|
set IMAGE=%REGISTRY%:%CONTAINER%-%ARCH%
|
|
|
|
echo Pulling container image: %IMAGE%
|
|
docker pull --platform "linux/%ARCH%" "%IMAGE%"
|
|
|
|
echo Running sanity tests in container
|
|
docker run ^
|
|
--rm ^
|
|
--platform "linux/%ARCH%" ^
|
|
--volume "%ROOT%:/root" ^
|
|
--entrypoint sh ^
|
|
"%IMAGE%" ^
|
|
/root/containers/entrypoint.sh %ARGS%
|